Excel 数式の結果に任意の名前を付ける (LET関数)
LET関数は2020年9月にMicrosoft365(Office365)のExcelに追加された新機能で、
数式を読みやすくしたりブックの計算速度を改善するための関数です。
何らかのプログラミング言語やマクロの経験者の方には、
数式に変数を利用できるようになったと考えると理解しやすいでしょう。
この記事では、その仕様と使い方を紹介します。
仕様
=LET(名前1,値1, ~ 名前126,値126,数式)
引数 | 省略時の値 | 説明 |
---|---|---|
名前1~126 | 省略不可 | 任意の命名を行います。 数字以外で始まる必要があります。 名前と値のセットは最低1つ指定する必要があります。 2以降は126まで指定可能です。 |
値1~126 | 省略不可 | 名前に対応する内容を指定します。 数値、文字列、数式のどれでも構いません。 |
数式 | 省略不可 | 最後(奇数個め)の引数が、 これまで定義した名前を使用する数式になります。 |
使い方
使用例
基本ケース
単純な使用例です。引数は以下の通りです。
=LET(a,25,a)
引数 | 設定値 |
---|---|
名前1 | a |
値1 | 25 |
数式 | a |
最後の数式でaという名前が25として扱われます。aは文字列ではないので"は付けません。
(範囲に名前を付けるのと同じ扱い)

値に文字列
値を"で囲めば文字列を指定可能です。
=LET(a,"ABC",a)
引数 | 設定値 |
---|---|
名前1 | a |
値1 | "ABC" |
数式 | a |

複数の名前を定義
複数の名前を定義するパターンです。
数式が長くなる場合は、名前と値のセット毎にセル内改行すると読みやすくなります。
また値2~126には、より左側で既に定義した名前を使用可能です。
=LET( a,3, b,a+2, a+b )
引数 | 設定値 |
---|---|
名前1 | a |
値1 | 3 |
名前2 | b |
値2 | a+2 |
数式 | a+b |
この場合、a=3、b=5で結果が8になります。

注意点
LET関数は有用な関数ですが新しい関数で知られておらず、
これまでのExcelの数式とは性質がかなり異なる関数です。
よって他の人が数式を見る可能性がある場合はLET関数について
説明しておく方が良いでしょう。
LET関数が有効なケース
意図なく使用すると数式が理解しにくくなってしまうため適切かを判断する必要があります。
同一の数式を複数回指定(冗長な数式)
例えば下の数式では同じVLOOKUP関数が2つあります。
=IF(VLOOKUP(C2,B6:C8,2,FALSE)="","",VLOOKUP(C2,B6:C8,2,FALSE))
このような場合は次のようにすると重複を除外して改善可能です。
=LET(vl,VLOOKUP(C2,B6:C8,2,FALSE),IF(vl="","",vl))
同一の数式を一つの名前にまとめることが出来るので、
関数を変更する際に1つだけで変えて、他の同一部分を変え忘れるようなことがなくなります。
単純なセル参照でも同じ場所への参照が多量にあれば効果があります。
これは中間セルを作って数式を省略するようなケースでも有効です。
また計算結果を格納するため関数の実行が1回で済むようになり計算速度が向上します。
(先ほどの例では2回のVLOOKUP関数実行が1回で済む)
特にFIND関数やXLOOKUP関数、VLOOKUP関数のような動作の重くなりがちな関数を
大量に使用している場合は特に計算速度の改善効果が高くなります。
数式が重いブックの場合、こちらと合わせてLET関数が改善のための検討候補になるでしょう。
複雑な数式を簡略化
複雑に入り組んだ数式を一定のかたまりで名前を付けて
簡略化することも有効です。(読みやすいかは命名や個人差あり)
重複除外と合わせて効果があります。
=MID(B3,FIND(C3,B3)+LEN(C3),FIND(D3,B3)-FIND(C3,B3)-LEN(C3))
C列の文字ととD列の文字の間の文字をMID関数で文字列を切り出すのがメインですが、
切り出し位置を決めるためのFIND関数とLEN関数が入り組んでいます。
また重複した数式も存在します。(背景色で色付けしている個所)

まず重複除外のみを行うと次の数式になります。
=LET( 前文字の開始位置,FIND(C3,B3), 前文字数,LEN(C3), MID(B3,前文字の開始位置+前文字数,FIND(D3,B3)-前文字の開始位置-前文字数) )
意味のある数式のかたまりに名前を付けて明確にすると以下のようになります。
=LET( 前文字の開始位置,FIND(C3,B3), 前文字数,LEN(C3), 切り出しの開始位置,前文字の開始位置+前文字数, 切り出し文字数,FIND(D3,B3)-前文字の開始位置-前文字数, MID(B3,切り出しの開始位置,切り出し文字数) )
これによりMID関数の数式の構造が明確になります。
Excelを効率的に習得したい方へ
当サイトの情報を電子書籍用に読み易く整理したコンテンツを
買い切り950円またはKindle Unlimited (読み放題) で提供中です。

Word-A4サイズ:1,400ページの情報量で
(実際のページ数はデバイスで変わります)
基本的な使い方、関数の解説(140種類)、
頻出テクニックと実用例(109種類)、
XLOOKUP関数、LET関数、シートビュー、LAMBDA関数、スピルなど便利な新機能を紹介。
体系的に学びたい方は是非ご検討ください。
アップデートなどの更新事項があれば随時反映しています。
なお購入後に最新版をダウンロードするには
Amazonへの問い合わせが必要です。